HSP程式交易論壇 >> 程式交易 >> 論壇主區 >> 經驗交流與分享 >> 「轉折精靈一號」讓程式交易更有創意!!
Hunta,2009-06-16 09:52:49
1.目前「轉折精靈一號」只能針對5分鐘緞,因為它是以5分鐘線為基礎來偵測轉折。
2.你可以在進場判斷時加上:
If 目前時間( 時 ) >= 9 And 目前時間( 時 ) < 12 Then
kimoze1,2009-06-19 00:05:52
歹勢
偶又來亂了
= =
以下是TS吃的
怎麼轉成HSP
input:stoploss(0.01);
variables:cdp(0),ah(0),nh(0),nl(0),al(0),longcount(0),shortcount(0);
if time = 0850 then
begin
cdp = (highD(1)+LowD(1)+2*CloseD(1))/4;
ah = cdp + (highD(1) - LowD(1));
nh = cdp*2 - LowD(1);
nl = 2*cdp - highD(1);
al = cdp - (highD(1) - LowD(1));
longcount = 0;
shortcount = 0;
end;
if (marketposition = -1 or marketposition = 0) and time > 0850 and cdp > 0 and Longcount = 0 then begin
Buy("CDP_B") 1 contracts next bar at ah stop;
end;
if (marketposition = 1 or marketposition = 0) and time > 0850 and cdp > 0 and shortcount = 0 then begin
Sell("CDP_S") 1 contracts next bar at al stop;
end;
if marketposition = 1 then begin
longcount = 1;
end;
if marketposition = -1 then begin
shortcount = -1;
end;
if marketposition = 1 then begin
exitlong("SlL") 1 contracts next bar at entryprice*(1 -stoploss) stop;
end;
if marketposition = -1 then begin
exitshort("SlS") 1 contracts next bar at entryprice*(1 + stoploss) stop;
end;
if time = 1340 then begin
exitlong("exitL");
exitshort("exitS");
cdp = 0;
ah = 0;
nh = 0;
nl = 0;
al = 0;
end;
Hunta,2009-06-19 21:00:47
程式碼如下:([COLOR=#ff0033]但必須更新至v2.9b版以上,才可執行[/COLOR])
10 Vh = 5分_開盤價
20 Vi = 0.01
30
40 If 5分_K線時間 = 850 Then
50 Va = ( 前1_300分_最高價 + 前1_300分_最低價 + 前1_300分_收盤價 * 2 ) / 4
60 Vb = Va + ( 前1_300分_最高價 - 前1_300分_最低價 )
70 Vc = Va * 2 - 前1_300分_最低價
80 Vd = Va * 2 - 前1_300分_最高價
90 Ve = Va - ( 前1_300分_最高價 - 前1_300分_最低價 )
100 Vf = 0
110 Vg = 0
120 End If
130
140 If 目前部位( 倉位多空 ) <= 0 And 前1_5分_K線時間 >= 850 And Va > 0 And Vf = 0
Then
150 Show [ K線下方 , ↑ ]
160 操作訊號( 空單平倉 , 1口 , Vh )
170 操作訊號( 多單建倉 , 1口 , Vh )
180 End If
190
200 If 目前部位( 倉位多空 ) >= 0 And 前1_5分_K線時間 >= 850 And Va > 0 And Vg = 0
Then
210 Show [ K線上方 , ↓ ]
220 操作訊號( 多單平倉 , 1口 , Vh )
230 操作訊號( 空單建倉 , 1口 , Vh )
240 End If
250
260 If 目前部位( 倉位多空 ) = 1 Then
270 Vf = 1
280 End If
290
300 If 目前部位( 倉位多空 ) = -1 Then
310 Vg = -1
320 End If
330
340 If 目前部位( 倉位多空 ) = 1 Then
350 If 前1_5分_收盤價 < 目前部位( 第 1 次成本價位 ) * ( 1 - Vi ) Then
360 Show [ K線下方 , ◎ ]
370 操作訊號( 多單平倉 , 1口 , Vh )
380 End If
390 End If
400
410 If 目前部位( 倉位多空 ) = -1 Then
420 If 前1_5分_收盤價 > 目前部位( 第 1 次成本價位 ) * ( 1 + Vi ) Then
430 Show [ K線上方 , ◎ ]
440 操作訊號( 空單平倉 , 1口 , Vh )
450 End If
460 End If
470
480 If 目前部位( 倉位多空 ) <> 0 And 前1_5分_K線時間 = 1335 Then
490 操作訊號( 多單平倉 , 1口 , Vh )
500 操作訊號( 空單平倉 , 1口 , Vg )
510 Show [ K線上方 , ※ ]
520 Va = 0
530 Vb = 0
540 Vc = 0
550 Vd = 0
560 Ve = 0
570 End If
程式下載 [URL=http://www.huntasoft.com/hsp/9004.rda]http://www.huntasoft.com/hsp/9004.rda[/URL]
kimoze1,2009-06-25 00:09:38
這是別的論壇看來的
我自己試寫程式
又失敗了
= =
只好再求助版主大大
H—-昨日高價
L-—昨日低價
C-—昨日收盤價
X=(H+L+C)÷3
當指數超過2X-2L+H做多
試寫如下
10 Va = 前1_300分_最高價
20 Vb = 前1_300分_最低價
30 Vc = 前1_300分_收盤價
40 Vd = ( Va + Vb + Vc ) / 3
50 Ve = 2 * Vd - 2 * Vb + Va
60 If 前1_5分_K線時間 > 850 And 前1_5分_收盤價 > Ve Then
70 Show [ K線下方 , ↑]
80 End If
執行後沒有反應
是不是哪裡寫錯了?
希望你協助解答
謝謝~~~
Hunta,2009-06-25 08:01:00
你可以在行號50與60之間加一個Debug(,Ve)
來知道Ve算出來是多少?
PS.策略程式執行後,打開十字線,移至K線圖上即可看到。
kimoze1,2009-06-25 09:21:31
已經改寫如下
10 Va = 前1_300分_最高價
20 Vb = 前1_300分_最低價
30 Vc = 前1_300分_收盤價
40 Vd = ( Va + Vb + Vc ) / 3
50 Ve = 2 * Vd - 2 * Vb + Va
60 Debug(,Ve)
70 If 前1_5分_K線時間 > 850 And 前1_5分_收盤價 > Ve Then
80 Show [ K線下方 , ↑]
90 End If
程式執行後
要在哪邊看運算值?
把十字線移到線線圖上沒看到任何東西耶?
Hunta,2009-06-25 10:26:30
以下是Run出來的結果
[IMG]http://www.huntasoft.com/hsp/0625-1.jpg[/IMG]
可能是你沒有更新至最新版,請至站務公告處更新!!
kimoze1,2009-06-25 11:56:07
安裝失敗耶~~
如下
http://tw.myblog.yahoo.com/jw!PWcKb_CYHx9iZQmOlF1e.BuQ_g--/article?mid=65&prev=-1&next=63
Hunta,2009-06-25 12:13:17
請先關閉HSP系統,然後再安裝一次,即可;若還是不行,請重開機,再安裝一次,即可。
Hunta,2009-06-25 12:16:05
另外,日後若有「與本文主題不同」的問題,最好是發一個新帖比較好,方便其他人參考,謝謝!!
97 1 2 8: 此主題共有22帖 此頁10帖 每頁12帖
[查看完整模式] LeadBBS 5.0 耗時62.5毫秒 請求2次
|